Saute-mouton pour Sharp PC1500 ( pas de programme )
tiré du magazine Hebdogiciel N°12

	Nécessite l'extension PETOOLS.

	Les moutons de gauche et les moutons de droite ! Non, ce n'est pas de la politique mais un casse-tête sur lequel il ne faut pas s'endormir !
	L'objectif du jeu est de transformer la figure du départ ( N°1 ), où les moutons se font face en la figure d'arrivée ( N°7 ), où les moutons se tournent le dos. Pour ce faire, utiliser les flèches < et > du clavier.

Programme :
10 REM "saute-mouton"
20 REM "auteur : antoine mahieu"
99 REM "initialisations"
100 WAIT 0:DIM M$(2)*20,M(8)
110 M$(0)="081C7C1C1C7C1C0E0606"
120 M$(1)="06060E1C7C1C1C7C1C08"
130 M$(2)="00000000000000000000"
140 FOR M=0 TO 1:D=4*M
150 FOR C=D TO D+2
160 GCURSOR C*12:GPRINT M$(M)
170 M(C+1)=M+1:NEXT C:NEXT M
180 GCURSOR 110:GPRINT "7F3E1C08";:PRINT " ou ";:GPRINT "081C3E7F"
190 C=4
200 REM "saisie"
210 A$=INKEY$:IF A$="" GOTO 210
220 A=ASC A$
230 IF A=8 IF C>1 LET B=C:C=C-1:GOTO 310
240 IF A=12 IF C<7 LET B=C:C=C+1:GOTO 310
250 IF A=13 GOTO 410
270 GOTO 210
300 REM "déplacement curseur"
310 BEEP 1,150,10:GCURSOR 12*B-2:GPRINT 0;0:GCURSOR 12*C-2:GPRINT "4040":GOTO 210
400 REM "étude du coup"
410 M=M(C):F=-SGN(M-1.5)
420 IF M=0 GOTO 610
430 G=C+F:IF M(G)=0 GOTO 510
440 G=C+2*F:IF M(G)=0 GOTO 510
450 GOTO 610
500 REM "opération acceptée"
510 IF G<1 OR G>7 GOTO 610
515 M(C)=0:GCURSOR (C-1)*12:GPRINT M$(2)
520 M(G)=M:GCURSOR (G-1)*12:GPRINT M$(M-1)
530 REM "test de fin de partie"
540 E=0:FOR I=1 TO 3:E=E+M(I):NEXT I:IF E=6 FOR J=5 TO 7:E=E+M(J):NEXT J:IF E=9 BEEP 5:CURSOR 18:PRINT "gagné!"
550 GOTO 210
600 REM "opération refusée"
610 CURSOR 18:WAIT 20:PRINT "refus ":WAIT 0:CURSOR 18:PRINT "     ":GOTO 210