5 WAIT 3:C=0:FOR I=1 TO 3:PRT "DES SOUS":IF KEY="$";C=C+1
15 NEXT I
18 C=C-1:IF C<=0;PRT "GAME OVER":END 
20 PRT "CREDIT:";C:T=3:B=0:P=0:E=0:U=0:O=0:M=1:D=0:R=0
25 FOR I=0 TO 8:A$(I)=".":NEXT I:$="GLADIATOR"
40 IF T=0 THEN 4000
50 PRT "BALL IN PLAY:";T:STOP 
60 W=18:IF O=1 THEN 120
65 PRT CSR 7;E+P
70 X=INT (RAN#*4
90 Z=2+INT (RAN#*8:Y=2+INT (RAN#*8
100 WAIT X:PRT CSR W;"*"
110 W=W-Y:IF W>Z THEN 70
120 X=2+INT (RAN#*12:GOTO X*100
200 X=1+INT (RAN#*20:PRT "CHAMPIGNON":WAIT 1
210 FOR I=1 TO X
220 U=U+100:PRT U:NEXT I:GOTO 2000
300 X=INT (RAN#*2:IF X=1 THEN 1200
360 M=M+1:PRT "BONUS *";M:IF M>=10;PRT "DECOMPTE":P=P+B*M:M=1:B=0
370 GOTO 60
400 WAIT 15:PRT "FLIP DROIT":PRT 
410 IF KEY="9" THEN 60
420 GOTO 3000
500 PRT "BONUS",200:B=B+200:GOTO 60
600 WAIT 15:PRT "FLIP GAUCHE":PRT 
610 IF KEY="D" THEN 60
620 GOTO 3000
700 PRT "RELANCEUR":X=INT (RAN#*6
710 FOR I=0 TO X STEP .25
720 WAIT I:U=U+50:PRT U:NEXT I:GOTO 2000
800 WAIT 0:Y=10:PRT "MINI-FLIP"
810 A=10+INT (RAN#*10
820 FOR I=1 TO A
825 PRT CSR 6;"==-";CSR Y;"*";CSR 12;"-=="
830 IF KEY="D";IF Y<>8 THEN 880
840 IF KEY="9";IF Y<>12 THEN 880
850 IF Y=8;Y=10:IF KEY<>"D" THEN 60
851 IF Y=12;Y=10:IF KEY<>"9" THEN 60
855 X=INT (RAN#*8:IF X>=4;Y=Y-1:GOTO 860
857 Y=Y+1
860 NEXT I
870 FOR I=1 TO A:U=U+500:PRT U:NEXT I:GOTO 2000
880 FOR I=1 TO 5:WAIT 3
890 PRT "TILT":PRT :NEXT I
895 B=10:M=0:GOTO 3005
900 PRT "SUPER BONUS",1000
910 B=B+1000:GOTO 60
1000 WAIT 3:PRT "FLASH",10:P=P+10:GOTO 60
1100 IF O=0;PRT "BLOCAGE":O=1:GOTO 60
1110 PRT "DEBLOCAGE":O=0:GOTO 60
1200 IF D=1 THEN 60
1205 X=INT (RAN#*9
1210 A$(X)=MID(X+1,1)
1220 FOR I=0 TO 8
1225 IF A$(I)<>MID(I+1,1) THEN 1250
1230 NEXT I:WAIT 3:P=P+5E4
1233 IF A0$="-";PRT "SPECIAL","CLAC":C=C+1:D=1:GOTO 60
1235 FOR I=1 TO 5
1236 FOR N=0 TO 8:PRT CSR N;A$(N):NEXT N
1237 NEXT I
1240 $="---------":R=1:T=T+1:GOTO 60
1250 FOR I=0 TO 8:PRT A$(I);:NEXT I:P=P+1E3
1255 PRT 1E3:GOTO 60
1300 GOTO 1200
2000 P=P+U:U=0:GOTO 60
3000 PRT "RATE"
3005 WAIT 10:P=P+U:E=E+P+B*M:M=1:T=T-1:O=0:PRT E:IF P+B=0;T=T+1
3010 P=0:B=0:IF R<>1 THEN 40
3015 R=0:WAIT 5
3020 PRT "SHOOT AGAIN":PRT 
3030 IF KEY="*" THEN 60
3040 GOTO 3015
4000 WAIT 3
4010 IF K<E;K=E:PRT "RECORD","CLAC":C=C+1
4020 PRT E;";R.:";K:STOP 
4030 IF E>=1E5;C=C+1:PRT "CLAC"
4040 IF E>=3E5;C=C+1:PRT "CLAC"
4050 X=INT (RAN#*10:A=-10:PRT "LOTERIE"
4060 FOR I=0 TO X
4070 A=A+10:PRT A
4080 NEXT I:IF A=100*FRAC (E/100;PRT "CLAC":C=C+1
4100 WAIT 10:PRT E:GOTO 18